Бесплатная проверка контрагентов в ФНС (общий модуль с алгоритмом). На примере выводим статус в список справочника контрагентов

Программирование - Практика программирования

Если вам интересно проверить контрагенте в ФНС, вам поможет данная публикация. Весь алгоритм работы строится на основе данных, полученных с сервиса http://npchk.nalog.ru совершенно бесплатно.

 

 Добрый день, Коллеги!

 

Возникла задача, понять и вытащить алгоритм проверки контрагентов в ФНС из типовой регламентированной отчетности. Алгоритм проверки на статус регистрации в ФНС и верность заполнения КПП. Задача развилась в идею вывести статус проверки ФНС в список справочника Контрагентов. Так же необходимо проверять статус ежедневно, чтобы держать базу с актуальными данными.

В современных конфигурациях (УТ11, КА2, ERP) данный алгоритм реализован на уровне типового решения, в старых конфигурациях в роде моей Комплексной Автоматизации 1.1 нет такой возможности, поэтому можно в путь пустить – творчество.

Программирование ведётся на конфигурации Комплексная Автоматизация 1.1.96.3 в режиме совместимости 8.2.13 (думаю, подойдёт к УТ10.3 и УПП),  обычные формы, но в управляемых как по мне было бы на много проще, но с другой стороны в тех конфигурациях велосипед уже есть.

 Что вы узнаете, прочитав данную статью: 

 

  1. Как получить данные из ФНС о контрагенте - http://npchk.nalog.ru
  2. Как вывести статус ФНС в табличную часть формы
  3. Создание в таблице формы колонки – картинки
  4. Как выделить цветом данные при выводе строк в таблице обычной формы и другое

Приступим.

Создаем новые объекты конфигурации

 

Сейчас все помешаны на расширениях, но не все могут этим воспользоваться, по этому представляю список доработок.

Общий список новых объектов:

  1. Общий модуль – «котПроверкаКонтрагентов»
  2. Картинка – «котСтатусыФНС»
  3. Регистр сведений «котКонтрагентыСтатусФНС»
  4. Регламентное задание «котЕжедневнаяПроверкаКонтрагентов»

 Общий модуль – «котПроверкаКонтрагентов» 

 

Создаем новый объект конфигурации – «общий модуль».

В моём случае название модуля – «котПроверкаКонтрагентов».

Настройки модуля:

 
 Программный код общего модуля

///////////////////////////////////////////////////////////////////////////////////
//	Данная разработка скачана из публикации:
//	//t1c.ru/public/755141/
//	Котов Д.В. (//t1c.ru/profile/564942/) 
//	Дата начала разработки - 30.01.2018
//	На основание бесплатного сервиса (http://npchk.nalog.ru) 
//	Важно понимать, что на данный момент сервис работает в тестовом режиме
///////////////////////////////////////////////////////////////////////////////////

Процедура ПроверкаКонтрагентов() Экспорт
	ДанныеПолучены = ЛОЖЬ;
	Запрос = Новый Запрос;
	Запрос.Текст = "ВЫБРАТЬ
	|	СтатусыФНС.Контрагент
	|ИЗ
	|	РегистрСведений.котКонтрагентыСтатусФНС КАК СтатусыФНС
	|ГДЕ
	|	СтатусыФНС.Статус = ""1""";	
	Результат = Запрос.Выполнить();
	Если Результат.Пустой() Тогда
		УстановитьФильтр = ЛОЖЬ;
	Иначе
		УстановитьФильтр = ИСТИНА;
		КонтрагентыКоторыеНеДействуют = Результат.Выгрузить();
	КонецЕсли;
	Запрос = Новый Запрос;
	Запрос.Текст = "ВЫБРАТЬ
	|	Контрагенты.Ссылка КАК Контрагент,
	|	Контрагенты.ИНН,
	|	Контрагенты.КПП,
	|	ВЫРАЗИТЬ("""" КАК СТРОКА(100)) КАК Состояние,
	|	&ТекущайДата КАК Дата
	|ИЗ
	|	Справочник.Контрагенты КАК Контрагенты
	|ГДЕ
	|	Контрагенты.ИНН <> """"" +
	?(УстановитьФильтр,"И НЕ Контрагенты.Ссылка В(&ГруппаКонтрагентов)","");
	Запрос.УстановитьПараметр("ТекущайДата",ТекущаяДата());
	Запрос.УстановитьПараметр("ГруппаКонтрагентов",КонтрагентыКоторыеНеДействуют);
	ДанныеКонтрагента = Запрос.Выполнить().Выгрузить();		
	ПолучитьРезультатПроверкиВебСервисом(ДанныеКонтрагента,ДанныеПолучены);
	Если ДанныеПолучены Тогда
		Для Каждого Строка Из ДанныеКонтрагента Цикл		
			НаборЗаписей = РегистрыСведений.котКонтрагентыСтатусФНС.СоздатьНаборЗаписей();
			НаборЗаписей.Отбор.Контрагент.Установить(Строка.Контрагент); 
			НаборЗаписей.Прочитать();
			Если НаборЗаписей.Количество() > 0 Тогда
				ЗаписьТекущая = НаборЗаписей.Получить(0);
				Пропускать = ЗаписьТекущая.Статус = "1"; 
			Иначе
				Пропускать = ЛОЖЬ;
			КонецЕсли;
			Если НЕ Пропускать Тогда
				НаборЗаписей.Очистить();
				НаборЗаписей.Записать();
				НоваяЗапись = НаборЗаписей.Добавить(); 		   
				НоваяЗапись.Контрагент = Строка.Контрагент; 
				НоваяЗапись.Статус = Строка.Состояние; 
				НаборЗаписей.Записать(ИСТИНА); 		
			КонецЕслИ;					
		КонецЦикла;
	КонецЕсли;
КонецПроцедуры

Функция ПроверитьКонтрагентаПоСсылке(Контрагент,Дата = Неопределено) Экспорт
	Если Дата = Неопределено Тогда
		Дата = ТекущаяДата();	
	КонецЕсли;
	Если Контрагент.ИНН <> "" Тогда 
		ДанныеПолучены = ЛОЖЬ;
		ДанныеКонтрагента = Новый ТаблицаЗначений;
		ДанныеКонтрагента.Колонки.Добавить("Контрагент", 	Новый ОписаниеТипов("СправочникСсылка.Контрагенты"));
		ДанныеКонтрагента.Колонки.Добавить("ИНН", 			Новый ОписаниеТипов("Строка",,Новый КвалификаторыСтроки(12)));
		ДанныеКонтрагента.Колонки.Добавить("КПП", 			Новый ОписаниеТипов("Строка",,Новый КвалификаторыСтроки(9)));
		ДанныеКонтрагента.Колонки.Добавить("Дата", 			Новый ОписаниеТипов("Дата",,,Новый КвалификаторыДаты(ЧастиДаты.Дата)));
		ДанныеКонтрагента.Колонки.Добавить("Состояние", 	Новый ОписаниеТипов("Строка",,Новый КвалификаторыСтроки(100)));
		ТекущийКонтрагент = ДанныеКонтрагента.Добавить();
		ТекущийКонтрагент.Контрагент = Контрагент;
		ТекущийКонтрагент.ИНН = Контрагент.ИНН;
		ТекущийКонтрагент.КПП = Контрагент.КПП;
		ТекущийКонтрагент.Дата = Дата;
		ПолучитьРезультатПроверкиВебСервисом(ДанныеКонтрагента,ДанныеПолучены);
		Если ДанныеПолучены Тогда
			Ответ = ДанныеКонтрагента[0].Состояние;	
			СостояниеФНС = СостояниеНаОсновеОтветаСервиса(Контрагент,Ответ);
		Иначе
			СостояниеФНС = "Сервер ФНС - не доступен, попробуйте позже";
		КонецЕсли;
	Иначе
		СостояниеФНС = "У контрагента не заполнен ИНН";
	КонецЕсли;	
	Возврат СостояниеФНС;
КонецФункции

Процедура ПолучитьРезультатПроверкиВебСервисом(ДанныеКонтрагентов, ЕстьДоступКВебСервисуФНС)	
	КоличествоКонтрагентов = ДанныеКонтрагентов.Количество();
	ЕстьДоступКВебСервисуФНС = ЕстьДоступКВебСервисуФНС();
	Если КоличествоКонтрагентов = 0 
		ИЛИ НЕ ЕстьДоступКВебСервисуФНС 
		Тогда
		Возврат;
	КонецЕсли;		
	Прокси = ПолучитьWSПрокси();	
	ПространствоИмен = "http://ws.unisoft/FNSNDSCAWS2/Request";	
	РазмерПорции = 10000; //возможно ограничения, в типовой так написано, максимум в запросе 10 000 контрагентов	
	КоличествоЗапросов = ?(КоличествоКонтрагентов % РазмерПорции = 0, КоличествоКонтрагентов / РазмерПорции, Цел(КоличествоКонтрагентов / РазмерПорции) + 1);		
	Для НомерПорции = 1 По КоличествоЗапросов Цикл 		
		МинимальныйНомерКонтрагента 	= Мин(РазмерПорции * (НомерПорции - 1), КоличествоКонтрагентов);
		МаксимальныйНомерКонтрагента 	= Мин(РазмерПорции * НомерПорции, КоличествоКонтрагентов) - 1;
		WSЗапрос = Прокси.ФабрикаXDTO.Создать(Прокси.ФабрикаXDTO.Тип(ПространствоИмен, "NdsRequest2"));		
		Для ИндексТекущегоКонтрагента = МинимальныйНомерКонтрагента По МаксимальныйНомерКонтрагента Цикл			
			ДанныеКонтрагента = ДанныеКонтрагентов[ИндексТекущегоКонтрагента];
			ДобавитьКонтрагентаВЗапросКСервису(WSЗапрос, Прокси, ПространствоИмен, ДанныеКонтрагента); 			
		КонецЦикла;		
		Если WSЗапрос.NP.Количество() = 0 Тогда
			Продолжить;
		КонецЕсли;	
		ЕстьДоступКВебСервисуФНС = ЕстьДоступКВебСервисуФНС();
		Попытка
			NdsResponse = Прокси.NdsRequest2(WSЗапрос);
		Исключение		
			ЗаписьЖурналаРегистрации("Проверка контрагентов.NdsRequest",УровеньЖурналаРегистрации.Ошибка,,, ПодробноеПредставлениеОшибки(ИнформацияОбОшибке()));			
			NdsResponse = Неопределено;	// Страхуемся от ошибки "Timeout wаs reached".
		КонецПопытки;		
		Если NdsResponse <> Неопределено Тогда
			ОбработатьОтветСервиса(NdsResponse, ДанныеКонтрагентов, МинимальныйНомерКонтрагента, МаксимальныйНомерКонтрагента);				
		КонецЕсли;		
	КонецЦикла; 	
КонецПроцедуры

Процедура ДобавитьКонтрагентаВЗапросКСервису(WSЗапрос, Прокси, ПространствоИмен, ДанныеКонтрагента)	
	Попытка	
		WSКонтрагент = Прокси.ФабрикаXDTO.Создать(Прокси.ФабрикаXDTO.Тип(ПространствоИмен, "NdsRequest2_NP"));	
		WSКонтрагент.INN = ДанныеКонтрагента.ИНН;	
		//ИП - проверяются БЕЗ указания КПП, иначе вернётся ошибка с кодом "10"
		Если ДанныеКонтрагента.Контрагент.ЮрФизЛицо = Перечисления.ЮрФизЛицо.ЮрЛицо Тогда
			КонтрагентЮР = ИСТИНА;
		Иначе
			КонтрагентЮР = ЛОЖЬ;
		КонецЕсли;
		Если ЗначениеЗаполнено(ДанныеКонтрагента.КПП) И КонтрагентЮР Тогда
			WSКонтрагент.KPP = ДанныеКонтрагента.КПП;
		Иначе
			WSКонтрагент.KPP = "";
		КонецЕсли;
		Если ЗначениеЗаполнено(ДанныеКонтрагента.Дата)Тогда
			WSКонтрагент.DT = ДатаСтрокой(ДанныеКонтрагента.Дата);
		КонецЕсли;
		WSЗапрос.NP.Добавить(WSКонтрагент);
	Исключение		
		ФиксацияОшибкиВЖурналеРегистрации("Проверка контрагентов. Ошибка в заполнение запроса по контрагенту код: " +
		ДанныеКонтрагента.Контрагент.Код,ИнформацияОбОшибке());
		ДанныеКонтрагента.Состояние = "W"; //Ошибка в данных		
	КонецПопытки; 				
КонецПроцедуры

Процедура ОбработатьОтветСервиса(NdsResponse, ДанныеКонтрагентовДляПроверкиСервисом, МинимальныйНомерКонтрагента, МаксимальныйНомерКонтрагента)	
	ИндексТекущегоОтвета = 0;
	Для ИндексТекущегоКонтрагента = МинимальныйНомерКонтрагента По МаксимальныйНомерКонтрагента Цикл 
		ДанныеКонтрагента = ДанныеКонтрагентовДляПроверкиСервисом[ИндексТекущегоКонтрагента];
		Попытка
			ОтветПоКонтрагенту 			= NdsResponse.NP[ИндексТекущегоОтвета];
			СостояниеВОтвете 			= ОтветПоКонтрагенту.State;
			ДанныеКонтрагента.Состояние = СостояниеВОтвете;			
		Исключение		
			ФиксацияОшибкиВЖурналеРегистрации("Проверка контрагентов.Обработка ответа от веб-сервиса",ИнформацияОбОшибке());		
		КонецПопытки;			
		ИндексТекущегоОтвета = ИндексТекущегоОтвета + 1;		
	КонецЦикла;				
КонецПроцедуры

Функция ЕстьДоступКВебСервисуФНС()	
	Возврат ПолучитьWSПрокси() <> Неопределено;	
КонецФункции

Функция ПолучитьWSПрокси() 	
	WSПрокси = Неопределено;
	Попытка
		WSПрокси = ОбщегоНазначения.WSПрокси(
		"http://npchk.nalog.ru/FNSNDSCAWS_2?wsdl",
		"http://ws.unisoft",
		"FNSNDSCAWS2",
		"FNSNDSCAWS2_Port",
		Неопределено,
		Неопределено,
		120);
	Исключение
		ФиксацияОшибкиВЖурналеРегистрации("Проверка контрагентов. Ошибка подключени WSПрокси.",ИнформацияОбОшибке())			
	КонецПопытки;
	Возврат WSПрокси;	
КонецФункции

Функция СостояниеНаОсновеОтветаСервиса(ДанныеКонтрагента, Ответ) Экспорт	
	Если Ответ = "0" Тогда
		Состояние = "Контрагент есть в базе ФНС";
	ИначеЕсли Ответ = "1" Тогда
		Если СтрДлина(ДанныеКонтрагента.ИНН) = 12 Тогда
			Состояние = "Не действует";
		Иначе
			Состояние = "Не действует или изменен КПП";
		КонецЕсли;
	ИначеЕсли Ответ = "3" Тогда
		Состояние = "КПП не соответствует данным базы ФНС";
	ИначеЕсли Ответ = "4" Тогда
		Состояние = "Контрагент отсутствует в базе ФНС";
	ИначеЕсли Ответ = "5" ИЛИ Ответ = "6" ИЛИ Ответ = "8" Тогда
		Состояние = "Ошибка. Некорректный ИНН";
	ИначеЕсли Ответ = "7" ИЛИ Ответ = "9" Тогда
		Состояние = "Ошибка. Некорректный КПП";
	ИначеЕсли Ответ = "11" ИЛИ Ответ = "12" Тогда
		Состояние = "Ошибка. Некорректная дата проверки";
	ИначеЕсли Ответ = "10" Тогда
		Состояние = "Ошибка. ИП заведено как юридическое лицо";
	ИначеЕсли Ответ = "W" Тогда
		Состояние = "Возникла ошибка заполнения данных контрагента";
	КонецЕсли;		
	Возврат Состояние;	
КонецФункции

Функция НомерКартинкиСтатуса(Статус) Экспорт	
	Если Статус = "0" Тогда
		СтатусКартинка = 3;
	ИначеЕсли Статус = "1" Тогда
		СтатусКартинка = 2;
	Иначе
		СтатусКартинка = 1;
	КонецЕсли;		
	Возврат СтатусКартинка;	
КонецФункции

Функция ДатаСтрокой(Дата)	
	Результат = Неопределено;
	Если ТипЗнч(Дата) = Тип("Строка") Тогда 
		Результат = Дата;
	ИначеЕсли ТипЗнч(Дата) = Тип("Дата") Тогда 
		Результат = Формат(Дата, "ДФ=dd.MM.yyyy");
	КонецЕсли;	
	Возврат Результат;	
КонецФункции

Процедура ФиксацияОшибкиВЖурналеРегистрации(ИмяСобытия,ИнформацияОбОшибке)
	ЗаписьЖурналаРегистрации(НСтр("ru = '"+ИмяСобытия+"'"),УровеньЖурналаРегистрации.Ошибка,,,ПодробноеПредставлениеОшибки(ИнформацияОбОшибке));	
КонецПроцедуры

Процедура ОчиститьРегистрСведенийСДаннымиПроверки() Экспорт
	НаборЗаписей = РегистрыСведений.котКонтрагентыСтатусФНС.СоздатьНаборЗаписей();
	НаборЗаписей.Записать();
КонецПроцедуры

 

 Картинка – «котСтатусыФНС» 

 

Создаем новый объект – Общие картинки, название «котСтатусыФНС».

Подгружаем картинку -         <<< скачайте

Описание иконок статуса ФНС:

 Регистр сведений – «котКонтрагентыСтатусФНС» 

 

Создаем регистр сведений – «котКонтрагентыСтатусФНС»

Основные

Периодичность: Непериодический

Режим записи: Независимый

Данные

Измерение – Контрагент – тип СправочникСсылка.Контрагенты

Ресурс – Статус – тип Строка (150)

Настройка прав за вами!

 Регламентное задание «котЕжедневнаяПроверкаКонтрагентов» 

 

Создаем объект конфигурации регламентное задание «котЕжедневнаяПроверкаКонтрагентов».

Имя метода – тыкаем по «лупе» и автоматически создаем процедуру в нашем модуле «котПроверкаКонтрагентов».

В созданную процедуру дописываем код вызова процедуры проверки контрагентов:

Процедура котЕжедневнаяПроверкаКонтрагентов() Экспорт
	ПроверкаКонтрагентов();
КонецПроцедуры

                                                                               

Доработка объектов конфигурации

 

Мы определились с новыми объектами, переходим к изменению объектов конфигурации.

Общий список изменений:

  1. Справочник – «Контрагенты», ФормаСписка
  2. Справочник – «Контрагенты», ФормаВыбора

Необходимо убедиться, что выше перечисленные объекты сняты с «замка».

 Общий принцип доработки обоих форм (повторяем и для ФормаСписка и для ФормаВыбора) 

 

Необходимо создать колонку «котСтатусФНС» в таблице формы – «СправочникСписок».

 ВНИМАНИЕ!  Не забывайте что 1С поддерживает копирование, да же колонок из одной формы в другую.

Добавляем колонку и настраиваем значение свойств:

Так же задаем свойства полю ввода:

Находим процедуру «ПриВыводеСтроки» событий таблицы формы «СправочникСписок» и проваливаемся в неё если есть или проваливаемся чтобы создать искомую:

В процедуру добавляем код:

	//Котов Д.В. +++ 31.01.2018
	//Так же можно выделять цветом всю строку целиком, тут ваш полёт фантазии не ограничен
	Если НЕ ОформлениеСтроки.ДанныеСтроки.ЭтоГруппа Тогда
		оформлениеСтроки.Ячейки.котСтатусФНС.ОтображатьТекст = ЛОЖЬ;
		оформлениеСтроки.Ячейки.котСтатусФНС.ОтображатьФлажок = ЛОЖЬ;
		оформлениеСтроки.Ячейки.котСтатусФНС.ОтображатьКартинку = ИСТИНА;		
		Запрос = Новый Запрос;
		Запрос.Текст = "ВЫБРАТЬ
		|	котКонтрагентыСтатусФНС.Статус
		|ИЗ
		|	РегистрСведений.котКонтрагентыСтатусФНС КАК котКонтрагентыСтатусФНС
		|ГДЕ
		|	котКонтрагентыСтатусФНС.Контрагент = &Контрагент";	
		Запрос.УстановитьПараметр("Контрагент", ОформлениеСтроки.ДанныеСтроки.Ссылка);	
		Результат = Запрос.Выполнить();	
		Если Результат.Пустой() Тогда
			ОформлениеСтроки.Ячейки.котСтатусФНС.ИндексКартинки = 0;
		Иначе
			Выборка = Результат.Выбрать();
			Выборка.Следующий();		
			ОформлениеСтроки.Ячейки.котСтатусФНС.ИндексКартинки = котПроверкаКонтрагентов.НомерКартинкиСтатуса(Выборка.Статус); 
		КонецЕсли;
	КонецЕсли;
	//Котов Д.В. --- 31.01.2018

Проверяем работу

 

Для проверки работы, так удобнее, нам потребуется простая обработка с двумя кнопками.

Одна "Проверить контрагентов" будет вызывать процедуру – 

котПроверкаКонтрагентов. котЕжедневнаяПроверкаКонтрагентов();

Вторая кнопка вызовет процедуру –

котПроверкаКонтрагентов. ОчиститьРегистрСведенийСДаннымиПроверки();

Запустив обработку, нажимаем кнопку «Проверить контрагентов» и ждём.

 ВНИМАНИЕ!  Выполнение кода может ни к чему не привести, так как сервер ФНС не стабилен! Может откликнуться только со 2 раза… 10…100 раза… или сразу. По этому если регистр сведений не заполнился, жмем ещё раз!

Когда видим, что регистр сведений успешно заполнен:

Открываем смело справочник контрагентов и видим радостную картинку:

Запускаем регламентное задание

 

Для запуска регламентного задания, вам потребуется - КонсольЗаданий:

Можно скачать с ИТС: https://its.1c.ru/db/metod8dev/content/3752/hdoc

Так же расширенная версия консоли заданий включена в "Инструменты разработчика": http://devtool1c.ucoz.ru/

Настраиваем задание, регулярность выполнение ваше пожелания:

Резюме

 

Функционал можно расширить, в моём случае помимо фиксации статуса ФНС будет так же фиксация в разрезе документов реализации и заказов, чтобы можно было подсвечивать заказы и реализации как в новых конфигурациях в зависимости от проблемности контрагента. Под проблемностью мы конечно понимает либо нет регистрации в ФНС или содержит ошибки КПП.

Кто внимательный то мог заметить, что в модуле есть функция ПроверитьКонтрагентаПоСсылке(Контрагент,Дата = Неопределено), данная функция позволяет по ссылке контрагента проверить его статус в ФНС, ответ ввиде строковой расшифровки, успешная – «Контрагент есть в базе ФНС». Если дата не указана, проверка производиться на текущую дату, иначе можно посмотреть допустим на момент сделки.

Так же вы можете расшифровать статус ФНС (он числовой от 0 до 12) с помощью функции СостояниеНаОсновеОтветаСервиса(ДанныеКонтрагента, Ответ).

Не забывайте важный момент – сервис работает в тестовом режиме – а это может быть всё что угодно!

Удачного кодинга!

 

 

Посткриптум

 

Наверное многие так же как я в режиме мистической совместимости 8.2.13 ведёт разработку и на управляемых формах. Так вот, всё, что я описывал в пункте «Доработка объектов конфигурации», намного проще реализуется не в таблице обычной формы, а в динамическом списке управляемой формы. Смотрите сами как легко (без кода почти) добавить колонку со статусом.

  1. Корректируем запрос добавив наш статус:

ВЫБРАТЬ
	Контрагенты.Код,
	Контрагенты.Наименование,
	Контрагенты.ИНН,
	Контрагенты.КПП,
	Контрагенты.НаименованиеПолное,
	ВЫБОР
		КОГДА котКонтрагентыСтатусФНС.Статус ЕСТЬ NULL
			ТОГДА 0
		КОГДА котКонтрагентыСтатусФНС.Статус = "0"
			ТОГДА 3
		КОГДА котКонтрагентыСтатусФНС.Статус = "1"
			ТОГДА 2
		ИНАЧЕ 1
	КОНЕЦ КАК ФНС
ИЗ
	Справочник.Контрагенты КАК Контрагенты
		ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.котКонтрагентыСтатусФНС КАК котКонтрагентыСтатусФНС
		ПО Контрагенты.Ссылка = котКонтрагентыСтатусФНС.Контрагент
  1. Перетаскиваем новую колонку в таблицу на форме и настраиваем ряд свойств:

Результат работы:

Как по мне динамический список и СКД это просто магия и песня!

Предлагаю вашему внимаю мою процедуру программного создания динамического списка:

 //t1c.ru/public/728597/

 Описание файлов к публикации 

 

Зачем тут файлы? Ну возможно, кому-то лень всё это повторить и проще накатить сравнением объединением готовый продукт, который легко ставится на КА 1.1, по всей видимости встанет и на УПП 1.3, УТ 10.3.

А также это единственная материальная благодарность автора, от которой не откажусь ;)

ПроверкаКонтрагентов.cf – готовый CF, содержащий рабочий алгоритм, описанный в данный статье, устанавливается сравнением объединением (кто умеет).

котИмитацияРаботыРегламетногоЗадания.epf – обработка, описанная выше.

котКонтрагенты.epf – обработка содержит пример работы динамического списка из посткриптума.

Скачать файлы

Наименование Файл Версия Размер
ПроверкаКонтрагентов.cf (Подсистема "Проверка контрагента" (готовый алгоритм))
.cf 56,70Kb
14.06.18
26
.cf 56,70Kb 26 Скачать
котИмитацияРаботыРегламетногоЗадания.epf (Обработка имитация запуска регламентного задания)
.epf 5,95Kb
01.02.18
3
.epf 5,95Kb 3 Скачать
котКонтрагенты.epf (Пример динамического списка)
.epf 6,91Kb
01.02.18
6
.epf 6,91Kb 6 Скачать

См. также

Лучшие комментарии
31. Дмитрий Котов (rpgshnik) 626 09.02.18 11:59 Сейчас в теме
Статью уже править не буду, но у себя добавил, советую и вам всем кто заинтересовался добавить ;)
Зачем это? Комментарии к публикации можете почитать и поймёте что почти три дня сервис лежал.
Сервис не стабильный - по этому лучше держать актуальные данные или что бы он отключался и пользователь понимал - что данной проверке нельзя доверять.

1. Константу - тип булево - включить/выключить функционал проверки контрагентов в ФНС
2. Константу - тип дата - содержит дату актуальной проверки

В формы которые я использую в справочнике Контрагентов я добавил в модуль формы переменную:

Перем ВыводитьСтатусФНС;


Затем я подвязал на открытие форм, процедуре ПриОткрытие

	ЭлементыФормы.СправочникСписок.Колонки.котСтатусФНС.Видимость = Константы.котПроверкаКонтрагентовВключен.Получить();
	ВыводитьСтатусФНС = НачалоДня(Константы.котПроверкаКонтрагентовФНСДатаПроверки.Получить()) = НачалоДня(ТекущаяДата());


Затем ещё скорректировал код при выводе строки:

	//Котов Д.В. +++ 31.01.2018
	//Так же можно выделять цветом всю строку целиком, тут ваш полёт фантазии не ограничен
	Если НЕ ОформлениеСтроки.ДанныеСтроки.ЭтоГруппа Тогда
		оформлениеСтроки.Ячейки.котСтатусФНС.ОтображатьТекст = ЛОЖЬ;
		оформлениеСтроки.Ячейки.котСтатусФНС.ОтображатьФлажок = ЛОЖЬ;
		оформлениеСтроки.Ячейки.котСтатусФНС.ОтображатьКартинку = ИСТИНА;
		Если ВыводитьСтатусФНС Тогда	//Котов Д.В. +++ 09.02.2018		
			Запрос = Новый Запрос;
			Запрос.Текст = "ВЫБРАТЬ
			|	котКонтрагентыСтатусФНС.Статус
			|ИЗ
			|	РегистрСведений.котКонтрагентыСтатусФНС КАК котКонтрагентыСтатусФНС
			|ГДЕ
			|	котКонтрагентыСтатусФНС.Контрагент = &Контрагент";	
			Запрос.УстановитьПараметр("Контрагент", ОформлениеСтроки.ДанныеСтроки.Ссылка);	
			Результат = Запрос.Выполнить();	
			Если Результат.Пустой() Тогда
				ОформлениеСтроки.Ячейки.котСтатусФНС.ИндексКартинки = 0;
			Иначе
				Выборка = Результат.Выбрать();
				Выборка.Следующий();		
				ОформлениеСтроки.Ячейки.котСтатусФНС.ИндексКартинки = котПроверкаКонтрагентов.НомерКартинкиСтатуса(Выборка.Статус); 
			КонецЕсли;
		Иначе
			ОформлениеСтроки.Ячейки.бгбСтатусФНС.ИндексКартинки = 0;	//Котов Д.В. +++ 09.02.2018
		КонецЕсли;
	КонецЕсли;
	//Котов Д.В. --- 31.01.2018
Показать


Результат данных действий простой:

1. Мы можем отключить алгоритм проверки статусов контрагентов в режиме предприятия онлайн!
2. Мы будем иметь только актуальные статусы, если каким-то образом проверка не прошла - тогда все иконки статусов будут "серыми".

Доработки общего модуля:

Ещё я добавил в общий модуль проверки - регламентной процедуры следующий код в самом начале:

Процедура котЕжедневнаяПроверкаКонтрагентов() Экспорт
	//Котов Д.В. +++ 09.02.2018 
	//Если механизм проверки не включен, тогда и проверять не нужно. Чтобы регламетной задание не отключать ;)
	Если НЕ Константы.котПроверкаКонтрагентовВключен.Получить() Тогда Возврат; КонецЕсли;
	//Решено актуализировать один раз на текущую дату, смотрите как вам удобнее.	
	Если НачалоДня(Константы.котПроверкаКонтрагентовФНСДатаПроверки.Получить()) = НачалоДня(ТекущаяДата()) Тогда Возврат; КонецЕсли;
	//Котов Д.В. --- 09.02.2018
	ПроверкаКонтрагентов();
КонецПроцедуры
Показать


А процедуре по проверке контрагентов "ПроверкаКонтрагентов()" добавил строчки по записи даты в константу:
Процедура ПроверкаКонтрагентов() Экспорт
	ДанныеПолучены = ЛОЖЬ;
	Запрос = Новый Запрос;
	Запрос.Текст = "ВЫБРАТЬ
	|	СтатусыФНС.Контрагент
	|ИЗ
	|	РегистрСведений.котКонтрагентыСтатусФНС КАК СтатусыФНС
	|ГДЕ
	|	СтатусыФНС.Статус = ""1""";	
	Результат = Запрос.Выполнить();
	Если Результат.Пустой() Тогда
		УстановитьФильтр = ЛОЖЬ;
	Иначе
		УстановитьФильтр = ИСТИНА;
		КонтрагентыКоторыеНеДействуют = Результат.Выгрузить();
	КонецЕсли;
	Запрос = Новый Запрос;
	Запрос.Текст = "ВЫБРАТЬ
	|	Контрагенты.Ссылка КАК Контрагент,
	|	Контрагенты.ИНН,
	|	Контрагенты.КПП,
	|	ВЫРАЗИТЬ("""" КАК СТРОКА(100)) КАК Состояние,
	|	&ТекущайДата КАК Дата
	|ИЗ
	|	Справочник.Контрагенты КАК Контрагенты
	|ГДЕ
	|	Контрагенты.ИНН <> """"" +
	?(УстановитьФильтр,"И НЕ Контрагенты.Ссылка В(&ГруппаКонтрагентов)","");
	Запрос.УстановитьПараметр("ТекущайДата",ТекущаяДата());
	Запрос.УстановитьПараметр("ГруппаКонтрагентов",КонтрагентыКоторыеНеДействуют);
	ДанныеКонтрагента = Запрос.Выполнить().Выгрузить();		
	ПолучитьРезультатПроверкиВебСервисом(ДанныеКонтрагента,ДанныеПолучены);
	Если ДанныеПолучены Тогда
		Для Каждого Строка Из ДанныеКонтрагента Цикл		
			НаборЗаписей = РегистрыСведений.котКонтрагентыСтатусФНС.СоздатьНаборЗаписей();
			НаборЗаписей.Отбор.Контрагент.Установить(Строка.Контрагент); 
			НаборЗаписей.Прочитать();
			Если НаборЗаписей.Количество() > 0 Тогда
				ЗаписьТекущая = НаборЗаписей.Получить(0);
				Пропускать = ЗаписьТекущая.Статус = "1"; 
			Иначе
				Пропускать = ЛОЖЬ;
			КонецЕсли;
			Если НЕ Пропускать Тогда
				НаборЗаписей.Очистить();
				НаборЗаписей.Записать();
				НоваяЗапись = НаборЗаписей.Добавить(); 		   
				НоваяЗапись.Контрагент = Строка.Контрагент; 
				НоваяЗапись.Статус = Строка.Состояние; 
				НаборЗаписей.Записать(ИСТИНА); 		
			КонецЕслИ;					
		КонецЦикла;
		//Котов Д.В. +++ 09.02.2018 
		ДатаПроверки = Константы.схпПроверкаКонтрагентовФНСДатаПроверки;
		ДатаПроверки.Установить(ТекущаяДата());
		//Котов Д.В. --- 09.02.2018
	КонецЕсли;
КонецПроцедуры
Показать
Остальные комментарии
Сортировка: Древо Сохранить
1. Евгений Смирнов (smirnov.es) 17 01.02.18 11:12 Сейчас в теме
Кот проверка контрагентов
Прикрепленные файлы:
madonov; sckif; ice-net; корум; bserge88; siddy; Lo1jke; jif; pavlov_dv; Артано; Interrupted; rpgshnik; +12 Ответить
2. Петр Малыгин (pm74) 107 01.02.18 12:24 Сейчас в теме
(0) оформление по "феншую" ))

добавим в "копилку" , вдруг пригодиться
denismal; Артано; rpgshnik; +3 Ответить
3. Сергей Ожерельев (Поручик) 4085 01.02.18 12:42 Сейчас в теме
Пригодится
madonov; корум; rpgshnik; +3 Ответить
4. Николай Беляев (freez1301) 219 01.02.18 22:26 Сейчас в теме
небольшое замечание - у Вас идет обращение к БД в процедуре при ВыводеСтроки. Запросов будет меньше, если поместить это в ПриПолученииДанных
корум; CSiER; rpgshnik; +3 Ответить
8. Дмитрий Котов (rpgshnik) 626 02.02.18 02:35 Сейчас в теме
(4) спасибо, я подумаю над этим.
5. Евгений Артемьев (yelloo) 01.02.18 22:47 Сейчас в теме
Странно, ведь было какое-то ограничение на количество запросов или ещё что, поэтому сервис вскоре стал платным (как и заполнение по ИНН). Далее 1с его в подписку запихало, что не удивительно. А теперь опять что ли бесплатно будет?:)
6. Евгений Артемьев (yelloo) 02.02.18 00:23 Сейчас в теме
У меня постоянно ответ "W", то бишь
Возникла ошибка заполнения данных контрагента
7. Евгений Артемьев (yelloo) 02.02.18 01:05 Сейчас в теме
(6) Извиняюсь, проверка на ЮрЛицо у меня не проходила, т.к. метаданные разные. Исправил.
Но заметил ещё кое-что - возвращаемый статус отличается от того, что сам сайт возвращает.
9. Дмитрий Котов (rpgshnik) 626 02.02.18 02:45 Сейчас в теме
(7) а какой именно статус возвращает?
12. Евгений Артемьев (yelloo) 02.02.18 09:48 Сейчас в теме
(9) Да я на ночь глядя не разобрался. Сейчас вижу, что все корректно, просто вы перефразировали статусы.
К примеру, статус 3 на сайте возвращает "Налогоплательщик с указанным ИНН зарегистрирован в ЕГРН", а у вас "КПП не соответствует данным базы ФНС".
Хотя в файле описании вообще "Налогоплательщик с указанным ИНН зарегистрирован в ЕГРН, КПП не соответствует ИНН или не указан*.
Вот я и запутался :)
Прикрепленные файлы:
Описание.doc
10. Константин Исиченко (IsiKosta) 725 02.02.18 06:00 Сейчас в теме
Что значат иконки в колонке "ФНС" ? (Какие статусы какой картинке соответствуют)
11. Дмитрий Котов (rpgshnik) 626 02.02.18 06:06 Сейчас в теме
13. Николай Васильев (vasilev2015) 624 02.02.18 11:14 Сейчас в теме
Статья симпатичная, но сам сервис плоховат. Иногда не отвечает, возвращает только статус. Пробовал использовать платный сервис, встроенный в бухгалтерию 3.0 - он еще хуже. Юридический адрес нашей фирмы возвращает с ошибкой. Заплаченные 4 тр сервис съел за неделю, хотя должно было хватить на 6 месяцев. Нет бочки меда без ложки дегтя.
rpgshnik; +1 Ответить
14. Дмитрий Котов (rpgshnik) 626 02.02.18 11:44 Сейчас в теме
(13) сервис плоховат, но он пока обрабатывает пакетами контрагентов и более менее правдивый. Остальные все платные... А так согласен, в статье то же писал, что может с 10-ого раза ответить))
15. Sergei Karpushev (brrart) 21 03.02.18 08:51 Сейчас в теме
(14) Это уж точно. что более менее. Не все данные правдивы. У нас реализована проверка через этот сервис, но пока тоже в тестовом режиме. Хотим в автоматическом режиме отказывать в отгрузках клиентам, не прошедшим данную проверку. Но пока не можем, потому как попадаются такие, которые эту проверку не проходят, а сервис той-же ФНС https://egrul.nalog.ru/ говорит что с ними всё ок. Смотрим в сторону Контура с это API.
rpgshnik; +1 Ответить
16. Дмитрий Котов (rpgshnik) 626 03.02.18 13:02 Сейчас в теме
17. Роман Ложкин (webester) 28 04.02.18 18:56 Сейчас в теме
ибится сердце перестало, вот заморочился то с оформлением...
al_ban; корум; Interrupted; +3 Ответить
18. Ринат Гильмутдинов (grin_64) 36 07.02.18 05:20 Сейчас в теме
Сервис больше недоступен?
19. Дмитрий Котов (rpgshnik) 626 07.02.18 05:38 Сейчас в теме
(18) странно буквально на днях работал все было отлично(( посмотрим сегодня.
Может поднимут...
20. Михаил С. (Milanick) 07.02.18 09:04 Сейчас в теме
Я у себя , по аналогии, ТНВЭД кода также реализовывал. Подгружались с сайта в регистр , а затем синхронизация с номенклатурным справочником :)
21. Михаил С. (Milanick) 07.02.18 09:05 Сейчас в теме
1С жулики, бесплатное превратили в платное :)
rpgshnik; +1 Ответить
22. Oksana Subbotina (OksanaSub) 50 07.02.18 11:55 Сейчас в теме
23. Дмитрий Котов (rpgshnik) 626 07.02.18 11:56 Сейчас в теме
(22) сейчас не ясная ситуация, сервис не мой, сервис принадлежит самим ФНС... может работы ведутся.
Сам пока жду и наблюдаю за ситуацией. Так как уже много, что на этом завязано.

ссылка на сам сайт - http://npchk.nalog.ru/
28. Дмитрий Котов (rpgshnik) 626 08.02.18 09:43 Сейчас в теме
24. shard (shard) 250 07.02.18 13:18 Сейчас в теме
Восхищен оформлением :)
rpgshnik; +1 Ответить
25. Дмитрий Котов (rpgshnik) 626 07.02.18 13:36 Сейчас в теме
26. Сергей Яхонтов (newbas) 595 07.02.18 13:39 Сейчас в теме
оформление отличное.
Сайт почему-то не работает
rpgshnik; +1 Ответить
27. Дмитрий Котов (rpgshnik) 626 08.02.18 09:42 Сейчас в теме
29. Ринат Гильмутдинов (grin_64) 36 08.02.18 10:35 Сейчас в теме
30. Дмитрий Котов (rpgshnik) 626 08.02.18 10:46 Сейчас в теме
31. Дмитрий Котов (rpgshnik) 626 09.02.18 11:59 Сейчас в теме
Статью уже править не буду, но у себя добавил, советую и вам всем кто заинтересовался добавить ;)
Зачем это? Комментарии к публикации можете почитать и поймёте что почти три дня сервис лежал.
Сервис не стабильный - по этому лучше держать актуальные данные или что бы он отключался и пользователь понимал - что данной проверке нельзя доверять.

1. Константу - тип булево - включить/выключить функционал проверки контрагентов в ФНС
2. Константу - тип дата - содержит дату актуальной проверки

В формы которые я использую в справочнике Контрагентов я добавил в модуль формы переменную:

Перем ВыводитьСтатусФНС;


Затем я подвязал на открытие форм, процедуре ПриОткрытие

	ЭлементыФормы.СправочникСписок.Колонки.котСтатусФНС.Видимость = Константы.котПроверкаКонтрагентовВключен.Получить();
	ВыводитьСтатусФНС = НачалоДня(Константы.котПроверкаКонтрагентовФНСДатаПроверки.Получить()) = НачалоДня(ТекущаяДата());


Затем ещё скорректировал код при выводе строки:

	//Котов Д.В. +++ 31.01.2018
	//Так же можно выделять цветом всю строку целиком, тут ваш полёт фантазии не ограничен
	Если НЕ ОформлениеСтроки.ДанныеСтроки.ЭтоГруппа Тогда
		оформлениеСтроки.Ячейки.котСтатусФНС.ОтображатьТекст = ЛОЖЬ;
		оформлениеСтроки.Ячейки.котСтатусФНС.ОтображатьФлажок = ЛОЖЬ;
		оформлениеСтроки.Ячейки.котСтатусФНС.ОтображатьКартинку = ИСТИНА;
		Если ВыводитьСтатусФНС Тогда	//Котов Д.В. +++ 09.02.2018		
			Запрос = Новый Запрос;
			Запрос.Текст = "ВЫБРАТЬ
			|	котКонтрагентыСтатусФНС.Статус
			|ИЗ
			|	РегистрСведений.котКонтрагентыСтатусФНС КАК котКонтрагентыСтатусФНС
			|ГДЕ
			|	котКонтрагентыСтатусФНС.Контрагент = &Контрагент";	
			Запрос.УстановитьПараметр("Контрагент", ОформлениеСтроки.ДанныеСтроки.Ссылка);	
			Результат = Запрос.Выполнить();	
			Если Результат.Пустой() Тогда
				ОформлениеСтроки.Ячейки.котСтатусФНС.ИндексКартинки = 0;
			Иначе
				Выборка = Результат.Выбрать();
				Выборка.Следующий();		
				ОформлениеСтроки.Ячейки.котСтатусФНС.ИндексКартинки = котПроверкаКонтрагентов.НомерКартинкиСтатуса(Выборка.Статус); 
			КонецЕсли;
		Иначе
			ОформлениеСтроки.Ячейки.бгбСтатусФНС.ИндексКартинки = 0;	//Котов Д.В. +++ 09.02.2018
		КонецЕсли;
	КонецЕсли;
	//Котов Д.В. --- 31.01.2018
Показать


Результат данных действий простой:

1. Мы можем отключить алгоритм проверки статусов контрагентов в режиме предприятия онлайн!
2. Мы будем иметь только актуальные статусы, если каким-то образом проверка не прошла - тогда все иконки статусов будут "серыми".

Доработки общего модуля:

Ещё я добавил в общий модуль проверки - регламентной процедуры следующий код в самом начале:

Процедура котЕжедневнаяПроверкаКонтрагентов() Экспорт
	//Котов Д.В. +++ 09.02.2018 
	//Если механизм проверки не включен, тогда и проверять не нужно. Чтобы регламетной задание не отключать ;)
	Если НЕ Константы.котПроверкаКонтрагентовВключен.Получить() Тогда Возврат; КонецЕсли;
	//Решено актуализировать один раз на текущую дату, смотрите как вам удобнее.	
	Если НачалоДня(Константы.котПроверкаКонтрагентовФНСДатаПроверки.Получить()) = НачалоДня(ТекущаяДата()) Тогда Возврат; КонецЕсли;
	//Котов Д.В. --- 09.02.2018
	ПроверкаКонтрагентов();
КонецПроцедуры
Показать


А процедуре по проверке контрагентов "ПроверкаКонтрагентов()" добавил строчки по записи даты в константу:
Процедура ПроверкаКонтрагентов() Экспорт
	ДанныеПолучены = ЛОЖЬ;
	Запрос = Новый Запрос;
	Запрос.Текст = "ВЫБРАТЬ
	|	СтатусыФНС.Контрагент
	|ИЗ
	|	РегистрСведений.котКонтрагентыСтатусФНС КАК СтатусыФНС
	|ГДЕ
	|	СтатусыФНС.Статус = ""1""";	
	Результат = Запрос.Выполнить();
	Если Результат.Пустой() Тогда
		УстановитьФильтр = ЛОЖЬ;
	Иначе
		УстановитьФильтр = ИСТИНА;
		КонтрагентыКоторыеНеДействуют = Результат.Выгрузить();
	КонецЕсли;
	Запрос = Новый Запрос;
	Запрос.Текст = "ВЫБРАТЬ
	|	Контрагенты.Ссылка КАК Контрагент,
	|	Контрагенты.ИНН,
	|	Контрагенты.КПП,
	|	ВЫРАЗИТЬ("""" КАК СТРОКА(100)) КАК Состояние,
	|	&ТекущайДата КАК Дата
	|ИЗ
	|	Справочник.Контрагенты КАК Контрагенты
	|ГДЕ
	|	Контрагенты.ИНН <> """"" +
	?(УстановитьФильтр,"И НЕ Контрагенты.Ссылка В(&ГруппаКонтрагентов)","");
	Запрос.УстановитьПараметр("ТекущайДата",ТекущаяДата());
	Запрос.УстановитьПараметр("ГруппаКонтрагентов",КонтрагентыКоторыеНеДействуют);
	ДанныеКонтрагента = Запрос.Выполнить().Выгрузить();		
	ПолучитьРезультатПроверкиВебСервисом(ДанныеКонтрагента,ДанныеПолучены);
	Если ДанныеПолучены Тогда
		Для Каждого Строка Из ДанныеКонтрагента Цикл		
			НаборЗаписей = РегистрыСведений.котКонтрагентыСтатусФНС.СоздатьНаборЗаписей();
			НаборЗаписей.Отбор.Контрагент.Установить(Строка.Контрагент); 
			НаборЗаписей.Прочитать();
			Если НаборЗаписей.Количество() > 0 Тогда
				ЗаписьТекущая = НаборЗаписей.Получить(0);
				Пропускать = ЗаписьТекущая.Статус = "1"; 
			Иначе
				Пропускать = ЛОЖЬ;
			КонецЕсли;
			Если НЕ Пропускать Тогда
				НаборЗаписей.Очистить();
				НаборЗаписей.Записать();
				НоваяЗапись = НаборЗаписей.Добавить(); 		   
				НоваяЗапись.Контрагент = Строка.Контрагент; 
				НоваяЗапись.Статус = Строка.Состояние; 
				НаборЗаписей.Записать(ИСТИНА); 		
			КонецЕслИ;					
		КонецЦикла;
		//Котов Д.В. +++ 09.02.2018 
		ДатаПроверки = Константы.схпПроверкаКонтрагентовФНСДатаПроверки;
		ДатаПроверки.Установить(ТекущаяДата());
		//Котов Д.В. --- 09.02.2018
	КонецЕсли;
КонецПроцедуры
Показать
32. Павел Апексимов (LomayaZakat) 27.03.18 15:29 Сейчас в теме
Не работает, при ответе выдает ошибку
33. Павел Апексимов (LomayaZakat) 28.03.18 08:10 Сейчас в теме
Проблема решилась на стороне фаервола
rpgshnik; +1 Ответить
34. Дмитрий Котов (rpgshnik) 626 02.04.18 05:52 Сейчас в теме
(33) отлично, в командировке был)) вообще сервис носит тестовый характер, было дело лежал почти неделю
38. Яков Коган (Yashazz) 2247 30.05.18 12:53 Сейчас в теме
Увидел фразу
WSПрокси = ОбщегоНазначения.WSПрокси(

и сразу захотелось резко минуснуть за столь откровенную хрень.
Оформление оформлением, но так не делают. Что это за отсылки к неведомым общим модулям?
39. Анастасия Сычева (AASycheva) 05.06.18 12:14 Сейчас в теме
Здравствуйте. Вы сняли cf с возможности скачивания? Почему-то не удается скачать его. В техподдержке сказали, что вы закрыли возможность скачивания. Но странно, ведь здесь все еще есть возможность отправить себе на почту. Да и поддержку вы ведете
40. Дмитрий Котов (rpgshnik) 626 06.06.18 04:14 Сейчас в теме
(39) Здравствуйте. Ни чего не закрывал и не чего не снимал, очень странно.
Судя по логу то после вас и до вас успешно скачали пользователи (скриншот ниже).

Вы первый раз скачиваете с инфостарта? Вам на почту должна придти ссылка, а через неё уже скачать.
Прямого скачивания (не через почту) здесь просто нет на инфостарте.
Прикрепленные файлы:
41. Анастасия Сычева (AASycheva) 07.06.18 20:39 Сейчас в теме
(40) нет, не в первый. В том-то и дело, что приходит ссылка, по которой невозможно скачать. В техподдержке, видимо, решили не разбираться и свалили всё на автора публикации. Спасибо, буду разбираться дальше
Оставьте свое сообщение